教你使用 WinGet 脚本自动安装和更新应用

alear 2025-06-10 14:12:48

　　系统之家 6 月 10 日消息， Windows 11 系统中如何通过 winget 脚本实现自动安装和更新应用。整个过程可以划分为三步，用户首先创建一份包含您希望安装在电脑上的所有应用的列表，然后生成脚本，最后决定如何运行脚本。

　　一. 实现的效果

　　通过 winget 脚本可以自动实现以下效果，可以设置为开机启动项，执行以下两项任务：

　　如果应用未安装，通过脚本自动安装。

　　如果应用已安装，脚本会检查是否有更新，并在检测到有更新后自动安装。

　　二. 生成应用列表

　　要创建一个使用 winget 安装和更新的应用列表，系统之家附上操作步骤如下：

　　1. 打开开始菜单

　　2. 搜索命令提示符(或终端)，右键点击顶部结果，并选择以管理员身份运行选项。

　　3. 输入以下命令以查找应用程序标识号，然后按回车键：

winget search-NAME

　　完成这些步骤后，命令将输出符合查询条件的应用程序。通常情况下，用户会希望使用一个单一的词来帮助您找到该应用程序。如果名称中包含空格，请使用 "引号"。

　　例如，如果用户想查找“VLC”应用程序的 winget 信息，可以使用 winget search vlc 命令，重复这些步骤并记录每个应用程序的 ID 值。

　　三. 创建 winget 脚本

　　要创建一个用于安装和更新应用程序的批处理文件，请按照以下步骤操作：

　　1. 打开开始菜单。

　　2. 搜索记事本并点击顶部结果以打开应用程序。

　　3. 将以下代码复制并粘贴到文本文件中：

@echo off
setlocal enabledelayedexpansion

:: List of application IDs
set apps=Microsoft.WindowsTerminal.Preview Microsoft.Edge.Dev Microsoft.PowerToys

for %%A in (%apps%) do (
    echo ---------------------------------------
    echo Processing %%A...
    
    :: Check if the app is installed by capturing the list output
    winget list --id %%A > temp_check.txt 2>&1

    findstr /C:"No installed package found" temp_check.txt >nul
    if !errorlevel! equ 0 (
        echo %%A not installed. Installing...
        winget install --id %%A --silent --accept-source-agreements --accept-package-agreements
    ) else (
        echo %%A is installed. Attempting upgrade...
        winget upgrade --id %%A --silent --accept-source-agreements --accept-package-agreements
        if !errorlevel! neq 0 (
            echo Upgrade failed for %%A or no update available.
        )
    )

    echo.
)

del temp_check.txt >nul 2>&1
endlocal

　　4. 在“set apps=”部分，注释您希望在计算机上安装和更新的应用程序，并使用空格分隔每个应用程序。

　　5. 点击文件并选择另存为选项。

　　6. 选择存储文件的位置。

　　7. 为脚本确认一个名称，并使用 .bat 文件扩展名。